/*=========================================================================
                           CAPTEUR PRESSION reglabe avec emetteur + DETECTEUR D EAU
Commande un servo à l’aide d’un capteur de pression MPX10GP et d un detecteur d eau
La profondeur Max pourra être modifiée en faisant varier la valeur profondeur maxi avec la voie 7:
(Valeur théorique du Signal_Capteur =495 à 525)
 =========================================================================*/
#include <SoftwareServo.h>            // Appel de la librairie servo
SoftwareServo servo_1;                // Declare le servo (Pin 0 pour AtTyni85)
const int Signal_Reglage = 4;         // Declare la variable (Signal_Reglage profondeur) sur le pin 4. Le récepteur voie 7 sera branche ici (Pin 4 pour AtTyni85)
const int Signal_Capteur = 1;         // Declare la variable (Signal_Capteur) sur le pin 2. Le Capteur sera branche ici (Pin 2 pour AtTyni85)
const int Signal_Recepteur = 3;       // Declare la variable (Signal_Recepteur) sur le pin 3. Le récepteur voie 6 sera branche ici (Pin 3 pour AtTyni85)
const int Signal_Detecteur = 1;       // Declare le fil du detecteur (Signal_eau) sur le pin 1 (Pin 1 pour AtTyni85)

int Val_SignalReglage;                // Variable pour stocker la valeur lue sur le Recepteur voie 7
int Val_SignalCapteur;                // Variable pour stocker la valeur lue sur le capteur de pression
int Val_SignalRecepteur;              // Variable pour stocker la valeur lue sur le Recepteur voie 6
int angle_potar = 0;                  // Declare la variable (Angle_potar emetteur)
int Angle_Servo = 0;                  // Declare la variable (Angle_Servo)
int Angle_Servo_vidange = 90;         // Declare la variable (Angle_Servo_vidange)
int Pression_Surface = 0;             // Declare la variable (pression en Surface)
int Profondeur_Max = 0;               // Declare la variable (Profondeur_Max)
int pression_Max = 0;                 // Declare la variable pression Max lue par le capteur de pression
int pression_Min = 0;                 // Declare la variable pression Min lue par le capteur de pression

// Valeur théorique du Signal_Recepteur voie 6 = 1073 à 2110 avec emetteur Futaba
int Max_voie6 = 2110;                 // Declare la variable valeur max de la voie 6
int Min_voie6 = 1073;                 // Declare la variable valeur min de la voie 6
// Valeur théorique du Signal_Reglage voie 7 = 960 à 2060  avec emetteur Futaba
int Max_voie7 = 2060;                 // Declare la variable valeur max de la voie 7
int Min_voie7 = 960;                  // Declare la variable valeur min de la voie 7
//=========================================================================
void setup()
{
  pinMode(Signal_Reglage, INPUT);         // Declare la variable Signal Reglage en entree
  pinMode(Signal_Capteur, INPUT);         // Declare la variable Signal Capteur en entree
  pinMode(Signal_Recepteur, INPUT);       // Declare la variable Signal Recepteur en entrée
  servo_1.attach(0);                      // Attache le servo au pin 0   (Pin 0 pour AtTyni85)
 
  pinMode(Signal_Detecteur, INPUT);       // Declare la variable Signal detecteur eau en entrée
  digitalWrite(Signal_Detecteur, HIGH);   // Activation du pull-up interne pour le detecteur d eau


 // calibration du capteur de pression pendant les 5 premieres secondes pour definir la pression en surface
  pression_Max = analogRead(Signal_Capteur);            // pression Max = valeur lue par le capteur de pression (definir une valeur)
  pression_Min = pression_Max;                          // pression Min = pression Max (definir une valeur)
  while (millis() < 5000) {
   Val_SignalCapteur = analogRead(Signal_Capteur);                           //Stocker la valeur du CAPTEUR dans la variable "Val_SignalCapteur"
   if (Val_SignalCapteur > pression_Max) {pression_Max = Val_SignalCapteur;} // Enregistre la valeur Max lue par le capteur de pression   
   if (Val_SignalCapteur < pression_Min) {pression_Min = Val_SignalCapteur;} // Enregistre la valeur Mini lue par le capteur de pression
    //---fin calibration capteur de pression
  }
  if (pression_Max > pression_Min) {Pression_Surface = pression_Max-((pression_Max-pression_Min)/2);}  // defini la pression moyenne en surface
  if (pression_Max == pression_Min) {Pression_Surface = pression_Max;}                                 //si pas d ecart prendre la valeur maxi en reference
}

//=========================================================================
void loop()
{
  noInterrupts();  
  //-----------------test Detection eau -----------------
   if (digitalRead(Signal_Detecteur)){  //------------ si pas de contact eau-----------
               
          //-----------------definir la profondeur maxi avec la telecommande----------------
            Val_SignalReglage = pulseIn(Signal_Reglage, HIGH, 30000);    // Donne à la variable (Val_SignalReglage) la valeur de (Signal_Reglage) lue sur le pin 4
            interrupts();                                                // Reactive les interruptions
            angle_potar = map(Val_SignalReglage, Min_voie7, Max_voie7, 0, 30);      // Calibre des valeurs du potar voie 7 de 0 à 30  
            angle_potar = constrain(angle_potar, 0, 30);                 // Fixe les valeurs minimum et maximum du potar
            Profondeur_Max = Pression_Surface + angle_potar;             // definir la profondeur maxi demandee avec la voie 7
            if ((Profondeur_Max > 550) or (Profondeur_Max < Pression_Surface))  {Profondeur_Max = Pression_Surface;}
          
          //-----------------test profondeur----------------
          Val_SignalCapteur = analogRead(Signal_Capteur);                  // Lit la valeur du Capteur de pression
               if (Val_SignalCapteur  <= Profondeur_Max) {     //--------si pression capteur < Profondeur_Max défini--------------
                  Val_SignalRecepteur = pulseIn(Signal_Recepteur, HIGH, 30000);  // Donne à la variable (Val_SignalRecepteur) la valeur de (Signal_Recepteur) lue sur le pin 3
                  interrupts();                                                  // Reactive les interruptions
                  Angle_Servo = map(Val_SignalRecepteur, Min_voie6, Max_voie6, 45, 135);   // Calibre des valeurs de pour le servo de 0 à 180  
                  Angle_Servo = constrain(Angle_Servo, 45, 135);                 // Fixe les valeurs minimum et maximum en degré de monservo
                  servo_1.write(Angle_Servo);                            // Positionne le servo suivant les ordes de la radiocommande  
                  delay(15);                                             // Delai pour que le servo atteigne sa position
                  SoftwareServo::refresh();                              // Rafraichissement bibliotheque servo
                 
               }else{     //-------------si pression capteur > Profondeur_Max ------------------
                  interrupts();                                          // Reactive les interruptions
                  servo_1.write(Angle_Servo_vidange);                    // Positionne le servo en vidange
                  delay(15);                                             // Delai pour que le servo atteigne sa position
                  SoftwareServo::refresh();                              // Rafraichissement bibliothèque servo
               } //-----------------fin test profondeur----------------    

  }else{  //----------- si Detection eau -------------------------
      interrupts();                                          // Reactive les interruptions
      servo_1.write(Angle_Servo_vidange);                    // Positionne le servo en vidange
      delay(15);                                             // Délai pour que le servo atteigne sa position
      SoftwareServo::refresh();                              // Rafraichissement bibliotheque servo
      }  //-----------------Fin Detection eau-----------------
 } //========================== FIN DU PROGRAMME=============================